rev: 3827f53bae88e48a594610914ba74b9512ead6dd tukan/testing/test_tmt.sc -rw-r--r-- 27.6 KiB View raw Log this file
3827f53bae88 — Leonard Ritter * more work on module system 3 months ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
#
    marching tetrahedra


#
    tetrahedral marching triangles

    step 1: identify by mask for each tet if its relevant vertices are partially set
    mask has 8 bits, 3 tets per bitarray = 2 x 24 bits
    all bits set or all bits not set = ignore, otherwise generate surface

    one tet is handled per thread

import ..tukan.voxel
let voxel = tukan.voxel

using import glm
using import glsl
using import Array
using import Box
using import struct
using import ..tukan.gl
using import ..tukan.bitmap
using import ..tukan.packing
using import ..tukan.random
using import ..tukan.color
using import ..tukan.perfect_hash
using import ..tukan.raytrace
using import ..tukan.sdf
using import ..tukan.sdl
using import ..tukan.rotation
using import ..tukan.brdf
using import ..tukan.normal
using import ..tukan.projection
using import ..tukan.derivative
using import ..tukan.isosurface
using import ..tukan.hash
using import .testfragment

# reserve 10MB for each voxel buffer
    at 4 bytes per voxel
let MAX_VOXELS = ((20 * (1 << 20)) // 4)

let BINDING_BUF_CELLS_IN = 1
let BINDING_BUF_CELLS_IN_INFO = 2
let BINDING_BUF_CELLS_OUT = 3
let BINDING_BUF_CELLS_OUT_INFO = 4
let BINDING_BUF_DRAW_CMD = 3
let BINDING_BUF_COMPUTE_CMD = 4
let BINDING_BUF_VERTEX_ATTR1_IN = 5
let BINDING_BUF_VERTEX_ATTR1_OUT = 6

let IMAGE_TARGET_RGBA32F = 1

let UNIFORM_LEVEL = 1
let UNIFORM_PROGRAM = 2
let UNIFORM_SCREEN_SAMPLER = 3
let UNIFORM_DIVISOR = 4

let ProgramVoxelizeInit = 0
let ProgramVoxelize = 1
let ProgramSimplify = 2

let sqrt3 = (sqrt 3.0)
let THREADSIZE = 256

let corner-vectors =
    arrayof vec3
        vec3 0 0 0
        vec3 1 0 0
        vec3 0 1 0
        vec3 1 1 0
        vec3 0 0 1
        vec3 1 0 1
        vec3 0 1 1
        vec3 1 1 1

run-stage;

struct CellValsInfo plain
    count : u32

struct CellVals plain
    # each entry holds a key
    entries : (array u32)

buffer buf-cells-in : CellVals
    binding = BINDING_BUF_CELLS_IN
    \ readonly coherent restrict

buffer buf-cells-in-info : CellValsInfo
    binding = BINDING_BUF_CELLS_IN_INFO
    \ readonly coherent restrict

buffer buf-cells-out : CellVals
    binding = BINDING_BUF_CELLS_OUT
    \ writeonly coherent restrict

buffer buf-cells-out-info : CellValsInfo
    binding = BINDING_BUF_CELLS_OUT_INFO
    \ coherent restrict

struct VertexAttr1 plain
    # cell key + simplex index, 4x u8 weights
    entries : (array uvec2)

buffer buf-vertex-attr1-in : VertexAttr1
    binding = BINDING_BUF_VERTEX_ATTR1_IN
    \ readonly coherent restrict

buffer buf-vertex-attr1-out : VertexAttr1
    binding = BINDING_BUF_VERTEX_ATTR1_OUT
    \ writeonly coherent restrict

uniform u-program : i32
    location = UNIFORM_PROGRAM

uniform u-level : i32
    location = UNIFORM_LEVEL

uniform smp-screen : sampler2D
    location = UNIFORM_SCREEN_SAMPLER

struct DispatchIndirectCommand plain
    num_groups_x : u32 = 1
    num_groups_y : u32 = 1
    num_groups_z : u32 = 1

struct DispatchIndirectCommandI plain
    command : DispatchIndirectCommand

struct DrawArraysIndirectCommand plain
    count : u32 = 0
    instanceCount : u32 = 0
    first : u32 = 0
    baseInstance : u32 = 0

struct DrawArraysIndirectCommandI plain
    command : DrawArraysIndirectCommand

buffer buf-compute-cmd : DispatchIndirectCommandI
    binding = BINDING_BUF_COMPUTE_CMD
    \ writeonly coherent restrict

buffer buf-draw-cmd : DrawArraysIndirectCommandI
    binding = BINDING_BUF_DRAW_CMD
    \ writeonly coherent restrict

uniform u-divisor : i32
    location = UNIFORM_DIVISOR

fn setup-compute-command ()
    local_size 1 1 1
    let divisor = ((deref u-divisor) as u32)
    buf-compute-cmd.command =
        DispatchIndirectCommand
            ((deref buf-cells-in-info.count) + divisor - 1:u32) // divisor
            1
            1
    ;

fn setup-draw-arrays-command ()
    local_size 1 1 1
    buf-draw-cmd.command =
        DrawArraysIndirectCommand
            deref buf-cells-in-info.count
            1
            0
            0
    ;

fn simple-sphere (p)
    (length p) - 0.5

fn nine-spheres (p)
    let x = (deref shglobals.time)
    r := (mix 0.1 0.2 ((sin x) * 0.5 + 0.5))
    d := (sqrt 0.5) * 0.4
    sdSmoothAnd
        sdSmoothOr
            (length p) - 0.5
            min
                (length (p - (vec3 d d d))) - r
                (length (p - (vec3 -d d d))) - r
                (length (p - (vec3 d -d d))) - r
                (length (p - (vec3 -d -d d))) - r
            0.1
        * -1.0
            min
                (length (p - (vec3 d d -d))) - r
                (length (p - (vec3 -d d -d))) - r
                (length (p - (vec3 d -d -d))) - r
                (length (p - (vec3 -d -d -d))) - r
        0.1

fn twoballs (p)
    let x = (deref shglobals.time)
    x := ((sin x) * 0.5 + 0.5) * 0.5
    sdSmoothOr
        (length (p - (vec3 0.0 0 x))) - 0.25
        (length (p - (vec3 0.0 0 -x))) - 0.25
        0.2

fn doubletori (p)
    let x = (deref shglobals.time)
    let xz =
        anglevector-rotate
            anglevector -x
            p.xz
    let p1 =
        vec3
            xz.x
            p.y
            xz.y
    let p2 =
        vec3
            anglevector-rotate
                anglevector x
                p.xy
            p.z

    'sdSmoothOr
        sdmDist
            sdTorus p1.xzy (vec2 0.5 0.05)
            sdMaterial
                vec4 1.0 0.5 0.3 1.0
        sdmDist
            sdTorus p2 (vec2 0.4 0.1)
            sdMaterial
                vec4 0.3 0.5 1.0 1.0
                roughness = 0.1
        0.2

fn two-boxes (p)
    let x = (deref shglobals.time)
    let p1 =
        vec3
            anglevector-rotate
                anglevector -x
                p.xy
            p.z
    let p2 =
        vec3
            p.x
            anglevector-rotate
                anglevector (x * 0.917)
                p.yz
    'sdSmoothOr
        sdmDist
            sdBox p1 (vec3 0.33)
            sdMaterial
                vec4 1.0 0.5 0.3 1.0
        sdmDist
            sdBox p2 (vec3 0.33)
            sdMaterial
                vec4 0.3 0.5 1.0 1.0
                roughness = 0.1
        0.2

fn two-boxes-merge (p)
    let d =
        vec3 0.3
    let sz =
        vec3 0.5
    let x = (deref shglobals.time)
    let sp1 =
        p - (vec3 0.0 0.0 -0.5)
    cwave := (sin (x * 10.0 + 2.0 * pi * 10.0 * (length sp1)))
    wave := cwave * 0.5 + 0.5
    r := (mix 1.0 0.2 ((sin x) * 0.5 + 0.5))
    'sdSmoothOr
        'sdSmoothAnd
            'sdSmoothOr
                sdmDist
                    #sdSphere
                        p - (vec3 0.01)
                        1.0
                    sdUberprim
                        p - (vec3 0.01)
                        vec4 1.0 1.0 0.05 0.05
                        vec3 0.5 0.05 0.0
                    sdMaterial
                        vec4 1.0 0.9 0.3 1.0
                        metallic = 1.0
                'sdSmoothOr
                    sdmDist
                        ((sdBox (p - d) (sz - 0.1)) - 0.1 + cwave * 0.01) / 1.3
                        sdMaterial
                            mix
                                vec4 1.0 0.5 0.3 1.0
                                (vec4 1.0 0.5 0.3 1.0) * 0.3
                                wave
                    sdmDist
                        sdBox (p + d) sz
                        sdMaterial
                            vec4 0.3 0.5 1.0 1.0
                            roughness = 0.2
                    0.5
                0.05
            sdmDist
                - (sdSphere sp1 r)
                sdMaterial
                    vec4 0.5 0.3 1.0 1.0
            0.1
        sdmDist
            sdEllipsoid
                p - (vec3 0.2 0.0 0.0)
                vec3 0.3 0.4 1.0
            sdMaterial
                vec4 0.3 1.0 0.5 1.0
        0.1

fn one-box (p)
    sdBox p (vec3 0.33)

fn matmapf (p)
    do
        p := p.yzx * 2.0
        (two-boxes-merge p) * 0.5
    #doubletori p
    #two-boxes p

# single sphere:
    256^3: 89240 cells (best: 0.3ms)
    1024^3: 1427240 cells (best: 3.5ms)
# min: 104567 at 256^3
fn mapf (p)
    #let x = ((radians (deref shglobals.time)) * 10.0)
    #let xz =
        anglevector-rotate
            anglevector -x
            p.xz
    #let p =
        vec3
            xz.x
            p.y
            xz.y
    #simple-sphere p
    #twoballs p
    #doubletori p
    #nine-spheres p
    #two-boxes p
    #one-box p
    (matmapf p) as f32

fn normalmapf (p r)
    - (sdNormalFast mapf p r)

fn subdivide-cell (key)
    let level = ((deref u-level) as u32)
    let r = (/ (f32 (1:u32 << level)))
    let d = (2.0 * r)
    #let rlimit =
        if (level == 8:u32) r
        else (sqrt3 * r)

    key := (key << 3:u32)

    ucoord := (unpack-morton3x10 key)
    coord := (vec3 ucoord) * d - 1.0 + r

    global cells : (array u32 8)
    global written = 0:u32

    fn test-cell (i ofs key coord r)
        let rlimit = (sqrt3 * r)
        key := key | i
        pos := coord + ofs
        let dist = (mapf pos)
        let hit = ((abs dist) < rlimit)
        if hit
            cells @ (deref written) = key
            written += 1:u32

    inline test-cell (i ofs)
        test-cell i ofs key coord r

    test-cell 0:u32 (vec3 0 0 0)
    test-cell 1:u32 (vec3 d 0 0)
    test-cell 2:u32 (vec3 0 d 0)
    test-cell 3:u32 (vec3 d d 0)
    test-cell 4:u32 (vec3 0 0 d)
    test-cell 5:u32 (vec3 d 0 d)
    test-cell 6:u32 (vec3 0 d d)
    test-cell 7:u32 (vec3 d d d)

    # commit
    if (written != 0:u32)
        let id = (atomicAdd buf-cells-out-info.count (deref written))
        for i in (range (deref written))
            buf-cells-out.entries @ (id + i) = (cells @ i)

fn offset-sample (p r)
    p
#
    let offset =
        vec3hashuv
            f32hashuv
                p + (((shglobals.frame * 256) & 4095) as f32)
    p + r * (offset * 2.0 - 1.0)

shared cell-samples : (array (array f32 8) (THREADSIZE // 8))

fn simplify-cell-build-samples (local-cell-index cell-index corner-index)
    let key = (deref (buf-cells-in.entries @ cell-index))
    let level = (((deref u-level) as u32) - 1)
    let r = (/ (f32 (1:u32 << level)))
    let d = (2.0 * r)

    ucoord := (unpack-morton3x10 key)
    coord := (vec3 ucoord) * d - 1.0

    coord := (offset-sample coord r)

    local vecs = corner-vectors
    ofs := (deref (vecs @ corner-index)) * d

    cell-samples @ local-cell-index @ corner-index =
        (mapf (coord + ofs)) / d
    ;

fn simplify-cell-build-simplices (local-cell-index cell-index simplex-index)
    let key = (deref (buf-cells-in.entries @ cell-index))

    let tetverts = 0x6cc99:u32
    k := simplex-index * 3:u32
    k1 := (tetverts >> k) & 7:u32
    k3 := (tetverts >> (k + 3:u32)) & 7:u32

    let dists = (cell-samples @ local-cell-index)
    let distmask =
        vec4
            dists @ 0
            dists @ k1
            dists @ 7
            dists @ k3

    let c = (tetfaces distmask)
    if (c != 0:u32)
        let id = (atomicAdd buf-cells-out-info.count 1:u32)
        buf-vertex-attr1-out.entries @ id =
            uvec2
                (key << 3:u32) | simplex-index
                packSnorm4x8 distmask

fn voxelize-init ()
    let index = (deref gl_GlobalInvocationID.x)
    subdivide-cell index

fn voxelize ()
    let index = (deref gl_GlobalInvocationID.x)
    if (index < buf-cells-in-info.count)
        subdivide-cell (deref (buf-cells-in.entries @ index))

fn simplify ()
    local_size THREADSIZE 1 1
    let index = (deref gl_GlobalInvocationID.x)
    cell-index := index // 8:u32
    let local-index = (deref gl_LocalInvocationID.x)
    local-cell-index := local-index // 8:u32
    subindex := local-index & 7:u32
    if (cell-index < buf-cells-in-info.count)
        simplify-cell-build-samples local-cell-index cell-index subindex
    barrier;
    #memoryBarrierShared;
    #if (cell-index < buf-cells-in-info.count)
        if (subindex < 6:u32)
            simplify-cell-build-simplices local-cell-index cell-index subindex

    let local-cell-index = (deref gl_LocalInvocationID.x)
    if (local-cell-index < (THREADSIZE * 6:u32 // 8:u32))
        subindex := local-cell-index % 6:u32
        local-cell-index := local-cell-index // 6:u32
        let index = ((gl_WorkGroupID.x * gl_WorkGroupSize.x) // 8:u32)
        cell-index := (index + local-cell-index)
        if (cell-index < buf-cells-in-info.count)
            simplify-cell-build-simplices local-cell-index cell-index subindex

fn supershader ()
    local_size THREADSIZE 1 1
    let mode = (deref u-program)
    switch mode
    case ProgramVoxelizeInit
        voxelize-init;
    case ProgramVoxelize
        voxelize;
    #case ProgramSimplify
        simplify;
    default
        ;;

fn calc-projection ()
    let aspect = (vec2 (/ (deref shglobals.aspect)) 1.0)
    'ifp-perspective ProjectionSetup aspect 0.1

inout-geometry geom_data : uvec2
fn rasterize-vert ()
    let index = ((deref gl_VertexID) as u32)
    let data = (deref (buf-vertex-attr1-in.entries @ index))
    geom_data.out = data
    ;

inout depthval : f32
inout modelpos : vec3
fn rasterize-geom ()
    input_primitive points
    output_primitive triangle_strip 4

    let data = (deref (geom_data.in @ 0))

    let key = data.x
    tetidx := (key & 7:u32)
    key := (key >> 3:u32) & 0x1ffffff

    let level = (((deref u-level) as u32) - 1)
    let r = (/ (f32 (1:u32 << level)))
    let d = (2.0 * r)
    ucoord := (unpack-morton3x10 key)
    coord := (vec3 ucoord) * d - 1.0
    coord := (offset-sample coord r)

    let tetverts = 0x6cc99:u32
    k := tetidx * 3:u32
    k1 := (tetverts >> k) & 7:u32
    k3 := (tetverts >> (k + 3:u32)) & 7:u32

    local p : (array vec3 4)
    p @ 0 = coord
    p @ 1 = coord + ((vec3 ((uvec3 k1 (k1 >> 1:u32) (k1 >> 2:u32)) & 1:u32)) * d)
    p @ 2 = coord + (vec3 d d d)
    p @ 3 = coord + ((vec3 ((uvec3 k3 (k3 >> 1:u32) (k3 >> 2:u32)) & 1:u32)) * d)

    let dists = (unpackSnorm4x8 data.y)

    let c i = (tetfaces dists)
    inline write-vertex (vertex-index)
        let shift = ((((c - 1) << 2) | vertex-index) * 2)
        let i0 i1 =
            (0x5000 >> shift) & 3
            (0xeef9 >> shift) & 3
        let i0 i1 = (deref (i @ i0)) (deref (i @ i1))
        let dist0 dist1 =
            dists @ i0
            dists @ i1
        let d0 d1 = (dist0 as f32) (dist1 as f32)
        let l = (tetlerp d0 d1)
        let coord = (mix (deref (p @ i0)) (deref (p @ i1)) l)

        modelpos.out = coord

        # rotate it a little
        embed
            let a = ((deref shglobals.time) * 0.2)
            let c s = (cos a) (sin a)
            coord :=
                vec3
                    c * coord.x - s * coord.z
                    coord.y
                    s * coord.x + c * coord.z

        coord :=
            coord + (vec3 0 0 1)

        let proj =
            calc-projection;

        let pcoord =
            'project proj
                vec4 coord 1.0

        depthval.out = coord.z
        gl_Position = pcoord
        EmitVertex;

    write-vertex 0:u32
    write-vertex 1:u32
    write-vertex 2:u32
    write-vertex 3:u32
    EndPrimitive;
    ;


fn pack-surfel-data (normal depth color matdata)
    let normal =
        bitcast (packSnorm2x16 (pack_normal_snorm normal)) f32
    let color =
        bitcast (packUnorm4x8 color) f32
    let matdata =
        bitcast (packUnorm4x8 matdata) f32
    vec4 normal matdata color depth

fn unpack-surfel-data (frag)
    let normal =
        unpack_normal_snorm (unpackSnorm2x16 (bitcast frag.x u32))
    let matdata =
        unpackUnorm4x8 (bitcast frag.y u32)
    let color =
        unpackUnorm4x8 (bitcast frag.z u32)
    _
        normal
        frag.w
        color
        matdata

out out_Color : vec4
    binding = 0
fn rasterize-frag ()
    let level = (((deref u-level) as u32) - 1)
    let r = (/ (f32 (1:u32 << level)))
    let coord = (deref modelpos.in)
    let dist = (matmapf coord)
    let material =
        dist.material
    let n =
        normalmapf coord (r / 32.0)

    # rotate it a little
    embed
        let a = ((deref shglobals.time) * 0.2)
        let c s = (cos a) (sin a)

        n :=
            vec3
                c * n.x - s * n.z
                n.y
                s * n.x + c * n.z

    out_Color =
        pack-surfel-data n
            deref depthval.in
            material.albedo
            vec4 material.roughness material.metallic 0 0

#uniform img-target-rgba32f : (image2D rgba32f)
    binding = IMAGE_TARGET_RGBA32F
    \ coherent writeonly restrict

uniform u-level : i32
    location = UNIFORM_LEVEL

fn mixdown (uv)
    #let t = (deref shglobals.time)
    let size =
        vec2 (deref shglobals.size)
    let uv2 =
        (uv * 2.0 - 1.0) * (vec2 shglobals.aspect 1)
    let uv = (ivec2 ((deref gl_FragCoord) . xy + 0.5))

    let col =
        texelFetch smp-screen uv 0
    let normal depth color matdata = (unpack-surfel-data col)
    if (depth == 0.0)
        return
            vec4 0.1 0.1 0.2 1
    let proj =
        calc-projection;
    let coord =
        vec3 ((uv2 * 2.0 - 1.0) * depth / proj.aspect) depth
    let rd = (normalize coord)

    let l =
        normalize
            vec3 0.5 -1.0 0.25
    let lambert =
        max 0.0 (dot normal l)

    let albedo = color.rgb
    let ambient =
        ((dot normal (vec3 0.0 -1.0 0.0)) * 0.5 + 0.5) * 0.1
    let exposure = 2.0

    let roughness = matdata.x
    let metallic = matdata.y
    let color =
        linear->sRGB
            tonemap
                * exposure
                    +
                        ambient * albedo * (1.0 - metallic)
                        * lambert
                            BRDF albedo
                                roughness
                                metallic
                                \ l rd normal

    return
        vec4 color 1.0
        #vec4
            #\ uv 0.0
            #normal * 0.5 + 0.5
            vec3
                (dot normal (normalize (vec3 0 -1 0))) * 0.5 + 0.5
            #normhue depth
            #normhue (radius / 16.0)
            #normhue (w / 8.0)
            1.0

fn visualize-buffer (uv)
    #let t = (deref shglobals.time)
    let size =
        vec2 (deref shglobals.size)
    let uv2 =
        (uv * 2.0 - 1.0) * (vec2 shglobals.aspect 1)
    let uv = (ivec2 ((deref gl_FragCoord) . xy + 0.5))

    let col =
        texelFetch smp-screen uv 0
    let normal depth color matdata = (unpack-surfel-data col)
    if (depth == 0.0)
        return
            vec4 0 0 0 1

    return
        vec4
            #normal * 0.5 + 0.5
            normhue depth
            #normhue (radius / 16.0)
            #color
            1.0

fn shader (uv)
    mixdown uv
    #visualize-buffer uv

inline main ()

    # pass overview:
        in: compute 4 * 4 * 4
        per thread:
            traverse 1/64th of octree
        for each leaf found:
            increase atomic counter in indirect draw call argument to obtain index
            append position + normal as vec4 (xyz, packed normal)
            append color as i32
                gamma compressed RGB10 values
                values >= 256 are emissive
                2 bits left for ?
            append material props as i32
                * roughness
                * metallic
                * film thickness
                * waxiness?
                * hue rotation?
                * UV activeness?
                * snowy glitter?

        in: indirect draw call argument
        out: rasterized voxel cubes

    let NUM_CMD_BUFFERS = 1

    global compute_cmd_buffers = (GL.CreateBuffer)
    setup-ssbo compute_cmd_buffers buf-compute-cmd NUM_CMD_BUFFERS

    global draw_cmd_buffers = (GL.CreateBuffer)
    setup-ssbo draw_cmd_buffers buf-draw-cmd NUM_CMD_BUFFERS

    let NUM_BUFFERS = 2

    global cell_info_buffers =
        arrayof GL.uint
            GL.CreateBuffer;
            GL.CreateBuffer;

    global cell_buffers =
        arrayof GL.uint
            GL.CreateBuffer;
            GL.CreateBuffer;
    let cell_info_buffer_sz = (sizeof u32)
    let cell_buffer_sz = ((sizeof u32) * MAX_VOXELS)
    for i in (range (NUM_BUFFERS as u32))
        let buf = (cell_info_buffers @ i)
        GL.NamedBufferData buf (i32 cell_info_buffer_sz) null GL.STREAM_COPY
        GL.BindBufferRange GL.SHADER_STORAGE_BUFFER (BINDING_BUF_CELLS_IN_INFO + i)
            \ buf 0:i64 (i64 cell_info_buffer_sz)
        let buf = (cell_buffers @ i)
        GL.NamedBufferData buf (i32 cell_buffer_sz) null GL.STREAM_COPY
        GL.BindBufferRange GL.SHADER_STORAGE_BUFFER (BINDING_BUF_CELLS_IN + i)
            \ buf 0:i64 (i64 cell_buffer_sz)

    global vertex_buffer = (GL.CreateBuffer)
    let vertex_buffer_sz = ((sizeof uvec2) * MAX_VOXELS)
    GL.NamedBufferData vertex_buffer (i32 vertex_buffer_sz) null GL.STREAM_COPY

    global fb-scene-color = (GL.CreateTexture GL.TEXTURE_2D)
    'setup fb-scene-color
        size = (ivec2 2048 2048)
        format = GL.RGBA32F
    do
        let h = 2048
        GL.ClearTexImage fb-scene-color 0 GL.RGBA GL.FLOAT null

    global rb-scene-depth = (GL.CreateRenderbuffer)
    setup-renderbuffer rb-scene-depth 2048 2048
        format = GL.DEPTH_COMPONENT
    global fb-scene = (GL.CreateFramebuffer)
    setup-framebuffer fb-scene
        color = fb-scene-color
        rb-depth = rb-scene-depth

    global vao-empty = (GL.CreateVertexArray)

    global pg-rasterize = (GL.CreateProgram)
    call
        attach-shaders (deref pg-rasterize)
            vertex = rasterize-vert
            geometry = rasterize-geom
            fragment = rasterize-frag
            #debug = true

    global pg-supershader = (GL.CreateProgram)
    call
        attach-shaders (deref pg-supershader)
            compute = supershader

    global pg-simplify = (GL.CreateProgram)
    call
        attach-shaders (deref pg-simplify)
            compute = simplify
            #debug = true

    global pg-setup-compute = (GL.CreateProgram)
    call
        attach-shaders (deref pg-setup-compute)
            compute = setup-compute-command
            #debug = true

    global pg-setup-draw = (GL.CreateProgram)
    call
        attach-shaders (deref pg-setup-draw)
            compute = setup-draw-arrays-command
            #debug = true

    inline per-frame-setup (size pg-test frame)

        GL.BindTextureUnit 0 fb-scene-color
        GL.Uniform smp-screen 0

        inline bind-read-buffer (i)
            GL.BindBufferRange GL.SHADER_STORAGE_BUFFER
                BINDING_BUF_CELLS_IN
                cell_buffers @ i
                \ 0:i64 (i64 cell_buffer_sz)
            GL.BindBufferRange GL.SHADER_STORAGE_BUFFER
                BINDING_BUF_CELLS_IN_INFO
                cell_info_buffers @ i
                \ 0:i64 (i64 cell_info_buffer_sz)

        inline clear-buffer-count (i)
            let buf = (cell_info_buffers @ i)
            let ptr =
                GL.MapNamedBufferRange buf 0 (sizeof u32)
                    | GL.MAP_WRITE_BIT
                        GL.MAP_INVALIDATE_BUFFER_BIT
                        #GL.MAP_UNSYNCHRONIZED_BIT
            let ptr = (bitcast ptr (mutable pointer CellValsInfo))
            ptr.count = 0:u32
            GL.UnmapNamedBuffer buf

        inline bind-write-buffer (i)
            clear-buffer-count i
            GL.BindBufferRange GL.SHADER_STORAGE_BUFFER
                BINDING_BUF_CELLS_OUT
                cell_buffers @ i
                \ 0:i64 (i64 cell_buffer_sz)
            GL.BindBufferRange GL.SHADER_STORAGE_BUFFER
                BINDING_BUF_CELLS_OUT_INFO
                cell_info_buffers @ i
                \ 0:i64 (i64 cell_info_buffer_sz)

        GL.UseProgram pg-supershader
        GL.BindBuffer GL.DISPATCH_INDIRECT_BUFFER compute_cmd_buffers

        local idx = 0
        local level = 0
        inline print-in-count (i)
            let buf = (cell_info_buffers @ i)
            let ptr =
                GL.MapNamedBufferRange buf 0 (sizeof u32)
                    GL.MAP_READ_BIT
            let ptr = (bitcast ptr (pointer CellValsInfo))
            print ptr.count
            GL.UnmapNamedBuffer buf

        inline init-voxels (l)
            level = l
            let i0 = (deref idx)
            idx = ((idx + 1) & 1)
            let i1 = (deref idx)
            let level = (deref level)
            GL.Uniform u-program ProgramVoxelizeInit
            GL.Uniform u-level level
            bind-read-buffer i0
            bind-write-buffer i1
            GL.DispatchCompute ((((1 << level) ** 3) // THREADSIZE) as u32) 1 1
            GL.MemoryBarrier GL.SHADER_STORAGE_BARRIER_BIT

        inline refine-voxels ()
            let i0 = (deref idx)
            idx = ((idx + 1) & 1)
            let i1 = (deref idx)
            level = level + 1
            let level = (deref level)
            GL.UseProgram pg-setup-compute
            GL.Uniform u-divisor THREADSIZE
            bind-read-buffer i0
            bind-ssbo compute_cmd_buffers buf-compute-cmd none 0
            GL.DispatchCompute 1 1 1
            GL.MemoryBarrier GL.COMMAND_BARRIER_BIT

            GL.UseProgram pg-supershader
            GL.Uniform u-program ProgramVoxelize
            GL.Uniform u-level level
            bind-read-buffer i0
            bind-write-buffer i1
            GL.DispatchComputeIndirect 0
            GL.MemoryBarrier GL.SHADER_STORAGE_BARRIER_BIT

        inline finalize-voxels ()
            let i0 = (deref idx)
            idx = ((idx + 1) & 1)
            let i1 = (deref idx)
            level = level + 1
            let level = (deref level)
            GL.UseProgram pg-setup-compute
            GL.Uniform u-divisor (THREADSIZE // 8)
            #GL.Uniform u-divisor THREADSIZE
            bind-read-buffer i0
            bind-ssbo compute_cmd_buffers buf-compute-cmd none 0
            GL.DispatchCompute 1 1 1
            GL.MemoryBarrier GL.COMMAND_BARRIER_BIT

            GL.UseProgram pg-simplify
            GL.Uniform u-level level
            bind-read-buffer i0
            bind-write-buffer i1
            GL.BindBufferRange GL.SHADER_STORAGE_BUFFER BINDING_BUF_VERTEX_ATTR1_OUT
                    \ vertex_buffer 0:i64 (i64 vertex_buffer_sz)
            GL.DispatchComputeIndirect 0
            GL.MemoryBarrier GL.SHADER_STORAGE_BARRIER_BIT

        inline draw-surface ()
            #print-in-count (deref idx)
            GL.MemoryBarrier (GL.ALL_BARRIER_BITS as u32)
            GL.BindBuffer GL.DRAW_INDIRECT_BUFFER draw_cmd_buffers
            GL.UseProgram pg-setup-draw
            bind-read-buffer (deref idx)
            bind-ssbo draw_cmd_buffers buf-draw-cmd none 0
            GL.DispatchCompute 1 1 1
            GL.MemoryBarrier GL.COMMAND_BARRIER_BIT
            do
                GL.BindFramebuffer GL.FRAMEBUFFER fb-scene
                GL.Viewport 0 0 (i32 size.x) (i32 size.y)
                GL.ClearColor 0 0 0 0
                GL.DepthFunc GL.GREATER
                GL.ClearDepthf 0
                GL.DepthRangef -1 1
                GL.Enable GL.CULL_FACE
                GL.CullFace GL.BACK
                GL.Enable GL.DEPTH_TEST
                GL.Clear
                    |
                        GL.COLOR_BUFFER_BIT
                        GL.DEPTH_BUFFER_BIT
                        GL.STENCIL_BUFFER_BIT

                GL.UseProgram pg-rasterize
                bind-read-buffer (deref idx)
                GL.BindBufferRange GL.SHADER_STORAGE_BUFFER BINDING_BUF_VERTEX_ATTR1_IN
                        \ vertex_buffer 0:i64 (i64 vertex_buffer_sz)
                GL.Uniform u-level (deref level)
                GL.BindVertexArray vao-empty
                GL.DrawArraysIndirect GL.POINTS null

                GL.Disable GL.DEPTH_TEST
                GL.Disable GL.CULL_FACE
                GL.BindFramebuffer GL.FRAMEBUFFER 0

        init-voxels 5
        refine-voxels;
        refine-voxels;
        refine-voxels;
        finalize-voxels;
        draw-surface;

    _ per-frame-setup shader

fn program ()
    render-fragment-shader main
        #debug = true
        size = (ivec2 512)


static-if true
    program;
else
    define f
        compile
            typify program
            'O3

    f;